@Title Sauvegarde de l'Etat du Systeme
@rem +----------------------------------------------------------+
@rem +	Sauvegarde de l'Etat du système				+
@rem +	Francois Dunoyer							+
@rem +	cree  : 06/12/2005						+
@rem +	Modif : 02/11/2007						+
@rem +----------------------------------------------------------+

:: valeurs par defaut si non configurées
if "%SysLog%"=="" Set Syslog=syslog.mondomaine.local
if "%LogDir%"=="" Set LogDir=c:\Logs
if "%SMTPS%"=="" Set SMTPS=smtp.Mondomaine.local
Set Destinataire=adm-svr@mondomaine.local

Set Ext=bkf
:: Par défaut définition du PC de centralisation des Sauvegardes
Set Cible=\\Poste_104
set Dossier=d$\sauvegardes\ES

Set Action=Sauvegarde l'Etat du Systeme
Set LogBrief=%LogDir%\SystemState.txt
if exist %LogBrief% del %Logbrief%

Rem Calcul de la chaine DATE AAAAMMJJ
set WD=%DATE:/=%
if "%WD:~4,1%"=="2" ( 
	set D=%WD:~4,4%%WD:~2,2%%WD:~0,2%
	set SNAPON=/snap:on
) ELSE set D=%WD:~9,4%%WD:~7,2%%WD:~5,2%

Set Message=%Action%
now %Message% >%LogBrief%

Set BackupName=%Cible%\%dossier%\%ComputerName%-ES-%D%.%Ext%
echo %Backupname%
pause
ntbackup.exe backup systemstate /n "Etat du systeme pour %ComputerName% au %DATE%" /d "ES-%ComputerName%-%D%" /F "%BackupName%" /v:no /r:no /rs:no /hc:off /m normal /j "ES-%ComputerName%-%D%" /l:f %SNAPON%

Rem Ajouts de Commentaires sur le fichier détaillé
now Backup effectue >>%LogBrief%
Echo Dossier : %Cible%\%dossier%\  >>%LogBrief%
Echo Fichier : ES-%D%%Ext%  >>%LogBrief%
Echo Le compte rendu detaille de l'operation est disponible >>%LogBrief%
echo dans le dossier \\%ComputerName%\Logs$ >>%LogBrief%
Echo Voir le fichier file:\\%ComputerName%\c$\Documents and Settings\%username%\Local Settings\Application Data\Microsoft\Windows NT\NTBackup\data\ >>%LogBrief%

rem Envoie du message par mail
Set Message=%Action%
blat %Logbrief% -to %destinataire% -subject "%ComputerName% : %Message%" -noh -f %computerName%@mondomaine.local -server %SMTPS%
klog -h %Syslog% -F user -L Information -m "%Message%"